Автор перевода: Майкл "Antares" Клишин	Предыдущая | Следующая | Оглавление

MovieClip.onLoad

Доступность

Flash Player 6.

Синтаксис

my_mc.onLoad = function() {
  // какой-либо код
}

Параметры

Нет.

Возвращает

Ничего.

Описание

Обработчик события; вызывается, когда мувиклип инициализируется и появляется на Таймлайне. Вы должны определить функцию, исполняемую при вызове обработчика. Вы можете задать эту функцию на Таймлайне, в методе класса, расширяющего класс MovieClip или связанного с символом в Библиотеке. Для более подробной информации смотри "Присваивание класса символу" в Использовании ActionScript во Flash.

Этот обработчик может использоваться только с мувиклипами, символ которых в Библиотеке связан с классом. Если Вы хотите, чтобы данный обработчик вызывался, когда загружается определенный мувиклип, например, при использовании MovieClip.loadMovie() для загрузки SWF файла, вы должны использовать onClipEvent(load) вместо данного обработчика. В противном случает обработчик будет вызываться, когда любой мувиклип появляется на Таймлайне.

Пример

В примере ниже показывается пример использования MovieClip.onLoad() вместе с setInterval() для проверки загрузки файла во время проигрывания ролика:

this.createEmptyMovieClip("tester_mc", 1);
tester_mc.loadMovie("http://www.yourserver.com/your_movie.swf");
function checkLoaded(target_mc:MovieClip) {
  var pctLoaded:Number = target_mc.getBytesLoaded()/target_mc.getBytesTotal()*100;
  if (!isNaN(pctLoaded) && (pctLoaded>0)) {
    target_mc.onLoad = doOnLoad;
    trace("clearing interval");
    clearInterval(myInterval);
  }
}
var myInterval:Number = setInterval(checkLoaded, 100, tester_mc);
function doOnLoad() {
  trace("Ролик загрузился!");
}

В примере ниже показывается другой способ реализации той же задачи:

this.createEmptyMovieClip("tester_mc", 1);
var mclListener:Object = new Object();
mclListener.onLoadInit = function (target_mc:MovieClip) {
  trace("Ролик загрузился!");
};
var image_mcl:MovieClipLoader = new MovieClipLoader();
image_mcl.addListener(mclListener);
image_mcl.loadClip("http://www.yourserver.com/your_movie.swf", tester_mc);

См. также

onClipEvent(), Класс MovieClipLoader

Посмотреть комментарии LiveDocs		Предыдущая | Следующая | Оглавление